12组Excel常用公式，很多人都在找！让你成为同事眼中的Excel高手

今天跟大家分享12个职场中必备的Excel函数公式，随着新函数的到来，很多经典的函数组合已经成为历史，大家以后遇到类似的问题，直接套用即可，让你成为同事眼中的Excel高手

一、提取数据中的唯一值

公式：=UNIQUE(B4:B14)

这个函数是一个新函数，作用就是提取数据区域的唯一值

用法：=UNIQUE(要提取数据区域)

二、身份证号码提取数据

提取生日：=TEXT(MID(A4,7,8),”0-00-00″)

提取年龄：=DATEDIF(TEXT(MID(A4,7,8),”0-00-00″),TODAY(),”y”)

提取性别：=IF(MOD(MID(A4,17,1),2)=1,”男”,”女”)

这个已经讲过好多次了，如果想要使用这个三个公式，只需要更改【A4】为你表格中数据的具体位置即可

三、合并同类项

公式：=TEXTJOIN(“,”,TRUE,IF($A$4:$A$18=D8,$B$4:$B$18,””))

TEXTJOIN函数的作用是使用分隔符进行数据连接，

第一参数：”,”，表示将逗号用作分隔符

第二参数：TRUE，表示忽略空值

第三参数：IF($A$4:$A$18=D8,$B$4:$B$18,””)，一个数组公式，可以返回班级对应的所有姓名

四、仅仅计算筛选数据

所谓的仅计算筛选数据，其实就是不计算隐藏的数据，这个要求我们需要使用SUBTOTAL函数，这个函数一般不用输入，我们将表格设置为超级表，勾选汇总行，再选择自己需要的计算类型即可，汇总行的本质就是SUBTOTAL

五、找出重复数据

公式：=IF(COUNTIF($B$4:B4,B4)=1,””,”是”)

这个公式本质是利用countif函数来判断的，如果数据出现重复，countif的结果就会大于1，最后再利用if函数输出结果即可

六、区间判断

公式：=IFS(B5>=90,”优秀”,B5>=80,”良好”,B5>=60,”及格”,B5<60,”不及格”)

这类问题非常常见，计算奖金提成，判断等级等等，最简单的方法就是利用ifs函数

语法：=IFS(第1个条件，第1个条件正确返回的结果，第2个条件，第2个条件正确返回的结果，……)条件与结果都是成对出现的，最多可以设置127对

七、一对多查询

公式：=FILTER(B4:B18,A4:A18=E4,”找不到结果”)

一对多查询，可以把它看做是一个筛选问题，而新函数FILTER就是一个筛选函数，可以轻松搞定这样的问题

用法：FILTER（要返回结果的区域，筛选条件，筛选不到结果返回的值）

八、隔行求和

公式：=SUMPRODUCT((MOD(ROW(C4:L9),2)=1)*C4:L9)

这个函数本质是一个SUMPRODUCT函数的单条件计数，库存的数据都在奇数行，所以我们用ROW函数获取数据的行号，然后再用MOD求得奇数行

九、隔列求和

公式：=SUMPRODUCT((MOD(COLUMN(B5:G14),2)=1)*B5:G14)

隔列求和原理也是一样的，现在【库存】都在奇数列，所以需要使用COLUMN获取对应的列号

十、多条件查询

公式：=LOOKUP(1,0/((A4:A12=E4)*(B4:B12=F4)),C4:C12)

多条件查询，我觉得使用LOOKUP函数是最简单的，大家只需要记得函数的书写规则即可

=LOOKUP(1,0/((条件1)*(条件2)),返回的结果列)，就是有几个条件，就在括号里写几个就行了

十一、关键字求和

公式：=SUMIF(A4:A15,”*车间*”,C4:C15)

关键字求和主要是利用了通配符，我将关键字【车间】的前后各链接一个星号，这样的话只要包含车间2个字就会被统计

十二、关键字查询

公式：=VLOOKUP(“*”&D2&”*”,$A$1:$B$6,2,FALSE)

这个跟关键字求和的原理是一样的，也是利用通配符，将关键字的各链接一个星号达到数据查询的目的

以上就是今天分享的12组函数公式，其中有你用过的吗？你又学到了哪些呢？可以留言讨论下

带你快速成为Excel高手